我平时电脑上都会安装VMware虚拟机，然后里面安装几个linux或者x86 安卓等等。但并非每次开机都会使用VMware虚拟机。

VMware虚拟机默认开机会有4个服务启动，对于一个有洁癖的人来说，总觉得让系统增加了负载。

VMware USB Arbitration Service
VMware NAT Service
VMware DHCP Service
VMware Authorization Service

于是我在services.msc中将这四个服务设置成了手动，每次我需要开启使用VMware的时候就打开services.msc，把这四个服务一个一个的启动，当我不需要使用VMware的时候就打开services.msc再一个一个关闭。当然大多数时间不使用的时候是直接关闭电脑的。

经过这一系列的操作，让我觉得好麻烦，于是想到了使用win的bat脚本，一键开启和关闭VMware服务。于是就有了下面的脚本：VMware服务管理.bat

@echo off
cls

fltmc >nul 2>&1 || (
    echo 请用管理员权限运行！
    pause >nul
    exit
)

set "ok=成功"
set "no=失败"
set "run=已运行"
set "stop=已停止"

:MENU
cls
echo ========================
echo VMware服务管理
echo ========================
echo 1. 启动服务
echo 2. 停止服务
echo 3. 退出
echo ========================
set "c="
set /p c=请选择(1/2/3)：

if "%c%"=="1" goto START
if "%c%"=="2" goto STOP
if "%c%"=="3" exit
echo 输入错误！
pause >nul
goto MENU

:START
cls
echo 正在启动服务...
echo.
echo 启动：VMware Authorization Service
net start VMAuthdService >nul 2>&1
if %errorlevel% equ 0 (echo 状态：%ok%) else if %errorlevel% equ 2 (echo 状态：%run%) else (echo 状态：%no%)
echo.
echo 启动：VMware DHCP Service
net start VMnetDHCP >nul 2>&1
if %errorlevel% equ 0 (echo 状态：%ok%) else if %errorlevel% equ 2 (echo 状态：%run%) else (echo 状态：%no%)
echo.
echo 启动：VMware NAT Service
net start "VMware NAT Service" >nul 2>&1
if %errorlevel% equ 0 (echo 状态：%ok%) else if %errorlevel% equ 2 (echo 状态：%run%) else (echo 状态：%no%)
echo.
echo 启动：VMware USB Arbitration Service
net start VMUSBArbService >nul 2>&1
if %errorlevel% equ 0 (echo 状态：%ok%) else if %errorlevel% equ 2 (echo 状态：%run%) else (echo 状态：%no%)
echo.
echo 操作完成！
pause >nul
goto MENU

:STOP
cls
echo 正在停止服务...
echo.
echo 停止：VMware USB Arbitration Service
net stop VMUSBArbService >nul 2>&1
if %errorlevel% equ 0 (echo 状态：%ok%) else if %errorlevel% equ 2 (echo 状态：%stop%) else (echo 状态：%no%)
echo.
echo 停止：VMware NAT Service
net stop "VMware NAT Service" >nul 2>&1
if %errorlevel% equ 0 (echo 状态：%ok%) else if %errorlevel% equ 2 (echo 状态：%stop%) else (echo 状态：%no%)
echo.
echo 停止：VMware DHCP Service
net stop VMnetDHCP >nul 2>&1
if %errorlevel% equ 0 (echo 状态：%ok%) else if %errorlevel% equ 2 (echo 状态：%stop%) else (echo 状态：%no%)
echo.
echo 停止：VMware Authorization Service
net stop VMAuthdService >nul 2>&1
if %errorlevel% equ 0 (echo 状态：%ok%) else if %errorlevel% equ 2 (echo 状态：%stop%) else (echo 状态：%no%)
echo.
echo 操作完成！
pause >nul
goto MENU

后面只需要在这个文件上右键选择管理员运行就可以快速开启和关闭这4个VMware服务了。
对了，这个bat脚本一定要使用gbk编码保存，要不中文会乱码的。